#!/bin/csh -fe

# Runnable example of ARP with REFMAC - restrained without hydrogens
# Created by Martyn Winn
# Updated for ARP/wARP 5.0 by PJX
# I have not attempted to optimise the parameters: for more
# authoritative examples, see
#           $CEXAM/unix/non-runnable/arp_waters_refmac.com
#           $CEXAM/unix/non-runnable/arp_waters_sfall.com
#           $CEXAM/unix/non-runnable/arp_waters_shelx.com

# 02/06/1998 awa: changes made as toxd.pdb now has chain ID. extend also
#                 replaced by mapmask.

# 01/03/2002 pjx: arp_warp 5.0 in CCP4 is renamed to arp_waters, to
#                 avoid a name clash with later versions from EMBL.

set name   = "${CCP4_SCR}/$$.toxd_"

# adjust cell dimensions 
pdbset XYZIN $CEXAM/toxd/toxd.pdb XYZOUT ${CCP4_SCR}/$$.tmp.pdb << e
CELL 73.58    38.73    23.19   90.00  90.00  90.00
e
#
# strip out waters
pdbset XYZIN ${CCP4_SCR}/$$.tmp.pdb XYZOUT ${name}0.pdb << e
SELECT CHAIN A S
e
#
rm ${CCP4_SCR}/$$.tmp.pdb
#
#
set last   =   0
set cycles =   5
set count  =   0
set data   = $CEXAM/toxd/toxd.mtz
#
set title  = 'TOXD'
set resol  = '36.8 2.3'
set cell   = '73.58   38.73   23.19   90.00   90.00   90.00'
#
# Grids for SF and FFT
set grid   = '152 96 64'
#
# Asym. unit limits compatible with arp
set xyzlim = '0 1 0 1 0 0.25'
#
# True space group
set symm   = '19'
#
# Space group for SF and FFT (if P1 - data should be extended to P1)
set sfsg   = 'P212121'
#
#
while ($count != $cycles)
@ next = $last + 1
#
#
protin XYZIN ${name}${last}.pdb \
       PROTOUT $CCP4_SCR/$$.protout \
       PROTCOUNTS $CCP4_SCR/$$.protcounts \
       << e
CHNNAM ID  A  CHNTYP 1 ROFFSE   0
CHNNAM ID  S  CHNTYP 2 ROFFSE  59
CHNNAM ID  W  CHNTYP 3 ROFFSE   0
CHNTYP 1 NTER 1 GLN 3   CTER 59 GLY 2 DISUL 0 MULP 0 CISPRO 0
CHNTYP 2 WAT
CHNTYP 3 WAT
SYMMETRY ${symm}
LIST FEW
TITLE  ${title}
END
e
#
#
refmac XYZIN ${name}${last}.pdb XYZOUT ${name}${next}.pdb \
       PROTOUT $CCP4_SCR/$$.protout \
       PROTSCR $CCP4_SCR/$$.protscr \
       PROTCOUNTS $CCP4_SCR/$$.protcounts \
       HKLIN $data HKLOUT ${name}${next}.mtz  << e
LABIN FP=FTOXD3 SIGFP=SIGFTOXD3  FREE=FreeR_flag
LABO FC=FC PHIC=PHIC    FWT=2FOFCWT PHWT=PH2FOFCWT -
                     DELFWT=FOFCWT  PHDELWT=PHFOFCWT
REFI TYPE RESTrained 
REFI RESI MLKF
REFI METH CDIR
REFI BREF ISOTropic 
!Scaling parameters
SCAL TYPE BULK   
WEIG EXPE MATR 0.5 
NCYC 3
MONI FEW
BINS 20
end
e
#
#
#
#
fft HKLIN ${name}${next}.mtz MAPOUT ${name}${next}_21.map << e
TITLE            2mFo-DFc 
SCALE            F1 1 0
RESOLUTION       ${resol}
FFTSYMMETRY      ${sfsg}
GRID             ${grid}
BINMAPOUT
LABIN            F1=2FOFCWT PHI=PH2FOFCWT FREE=FreeR_flag
END
e
#
#
mapmask MAPIN ${name}${next}_21.map MAPOUT ${name}${next}_21.ext << e
XYZLIM ${xyzlim}
END
e
#
#
/bin/rm ${name}${next}_21.map
#
#
fft HKLIN ${name}${next}.mtz MAPOUT ${name}${next}_11.map << e
TITLE            mFo-DFc 
SCALE            F1 1 0
RESOLUTION       ${resol}
FFTSYMMETRY      ${sfsg}
GRID             ${grid}
BINMAPOUT
LABIN            F1=FOFCWT PHI=PHFOFCWT FREE=FreeR_flag
END
e
#
#
mapmask MAPIN ${name}${next}_11.map MAPOUT ${name}${next}_11.ext << e
XYZLIM ${xyzlim}
END
e
#
#
/bin/rm ${name}${next}_11.map
#
#
arp_waters XYZIN ${name}${next}.pdb \
 MAPIN1 ${name}${next}_21.ext \
 MAPIN2 ${name}${next}_11.ext XYZOUT TMP.RES << e
MODE UPDATE WATERS
CELL       ${cell}
SYMM       ${symm}
RESOLUTION ${resol}
! Removal based on 2mFo-DFc map
REMOVE     ATOMS 5 CUTSIGMA 0.8 MERGE 2.2
! Addition based on mFo-DFc map
FIND       ATOMS 5 CHAIN W CUTSIGMA AUTO
REFINE     WATERS
END
e
#
#
/bin/rm ${name}${next}.mtz
/bin/rm ${name}${next}_21.ext
/bin/rm ${name}${next}_11.ext
/bin/rm ${name}${next}.pdb
mv TMP.RES ${name}${next}.pdb
#
#
@ last++
@ count++
end

#
# select waters
pdbset XYZIN ${name}${next}.pdb XYZOUT waters_all.pdb << e
SELECT CHAIN W
e
#

cp -p ${name}${next}.pdb toxd_arp_waters.pdb

# Check which of the waters found were in the original file.
# I make it 12 out of 19.

watpeak XYZIN $CEXAM/toxd/toxd.pdb PEAKS waters_all.pdb \
        XYZOUT waters.pdb <<EOF
SYMM       ${symm}
DIST 0.0 1.0
END
EOF
#

/bin/rm -f ${CCP4_SCR}/$$.*